Public Class Thing

   Private m_X As Integer
   Private m_Y As Integer
   Private m_Width As Integer
   Private m_Height As Integer
   Private m_IsDragging As Boolean

   Public Sub New(ByVal Rnd As Random, ByVal Width As Integer, _
ByVal Height As Integer)
      Me.m_X = Rnd.Next(Width - 50)
      Me.m_Y = Rnd.Next(Height - 25)
      Me.m_Width = 100
      Me.m_Height = 50
   End Sub

   Public ReadOnly Property CenterX() As Integer
      Get
         Return Me.X + CType(Me.Width / 2, Integer)
      End Get
   End Property

   Public ReadOnly Property CenterY() As Integer
      Get
         Return Me.Y + CType(Me.Height / 2, Integer)
      End Get
   End Property

   Public Function GetDistance(ByVal FromX _
As Integer, ByVal FromY As Integer) As Double
      Dim DistX As Double = Math.Abs(Me.CenterX - FromX)
      Dim DistY As Double = Math.Abs(Me.CenterY - FromY)
      Dim Dist As Double = (DistX + DistY)
      If Dist = 0 Then
         Return 0
      Else
         Return Dist / 2
      End If
   End Function

   Public Property X() As Integer
      Get
         Return Me.m_X
      End Get
      Set(ByVal value As Integer)
         Me.m_X = value
      End Set
   End Property

   Public Property Y() As Integer
      Get
         Return Me.m_Y
      End Get
      Set(ByVal value As Integer)
         Me.m_Y = value
      End Set
   End Property

   Public Property Width() As Integer
      Get
         Return Me.m_Width
      End Get
      Set(ByVal value As Integer)
         Me.m_Width = value
      End Set
   End Property

   Public Property Height() As Integer
      Get
         Return Me.m_Height
      End Get
      Set(ByVal value As Integer)
         Me.m_Height = value
      End Set
   End Property

   Public Property IsDragging() As Boolean
      Get
         Return Me.m_IsDragging
      End Get
      Set(ByVal value As Boolean)
         Me.m_IsDragging = value
      End Set
   End Property

   Public Sub Draw(ByVal G As System.Drawing.Graphics)
      G.FillRectangle(Brushes.Green, Me.X, Me.Y, Me.Width, Me.Height)
      G.DrawRectangle(Pens.Black, Me.X, Me.Y, Me.Width, Me.Height)
      If Me.IsDragging Then
         G.DrawRectangle(Pens.Black, Me.X - 2, Me.Y - 2, Me.Width + 4, Me.Height + 4)
      End If
   End Sub

   Public Function HitTest(ByVal PosX As Integer, ByVal PosY As Integer) As Boolean
      Return (PosX >= Me.X _
AndAlso PosX <= (Me.X + Me.Width) _
AndAlso PosY >= Me.Y AndAlso PosY <= (Me.Y + Me.Height))
   End Function

End Class

The ThingList keeps track of all dragable objects, and makes sure that all are positioned within the visible area of the Panel.

Public Class ThingList
   Inherits System.Collections.CollectionBase

   Public Function Add(ByVal O As Thing) As Integer
      Return List.Add(O)
   End Function

   Default Public ReadOnly Property Item(ByVal Index As Integer) As Thing
      Get
         Return CType(List(Index), Thing)
      End Get
   End Property

   Public Sub Draw(ByVal G As System.Drawing.Graphics)
      For Each O As Thing In Me
         O.Draw(G)
      Next
   End Sub

   Public Function GetObjectAt(ByVal MouseX As Integer, ByVal MouseY As_
 Integer) As Thing
      If Me.Count > 0 Then
         For Each O As Thing In Me
            If O.HitTest(MouseX, MouseY) Then
               Return O
            End If
         Next
         Return Nothing
      Else
         Return Nothing
      End If
   End Function

   Public Function GetObjectIfClose(ByVal MouseX As Integer, _
ByVal MouseY As Integer) As Thing
      If Me.Count > 0 Then
         Dim CloseIndex As Integer = -1
         Dim CloseDistance As Double = 60
         For I As Integer = 0 To Me.Count - 1
            Dim Distance As Double = Me(I).GetDistance(MouseX, MouseY)
            If Distance < CloseDistance Then
               CloseDistance = Distance
               CloseIndex = I
            End If
         Next
         If CloseIndex >= 0 Then
            Return Me(CloseIndex)
         Else
            Return Nothing
         End If
      Else
         Return Nothing
      End If
   End Function

   Public Sub ResetIsDragging()
      For Each O As Thing In Me
         O.IsDragging = False
      Next
   End Sub

   Public Function MoveToVisibleArea(ByVal S As Size) As Boolean
      Dim Ret As Boolean = False
      For Each O As Thing In Me
         If O.X < 0 Then
            O.X += 2
            Ret = True
         End If
         If O.Y < 0 Then
            O.Y += 2
            Ret = True
         End If
         If (O.X + O.Width) > S.Width Then
            O.X -= 2
            Ret = True
         End If
         If (O.Y + O.Height) > S.Height Then
            O.Y -= 2
            Ret = True
         End If
      Next
      Return Ret
   End Function

End Class

The form (contains a panel named Panel1) basically keeps track of mouse actions. This does not include the drag and drop events of the Control class, because that deals with dragging and dropping controls, not GDI+ objects.

Public Class Form1

   Private L As ThingList
   Private IsDragging As Boolean
   Private DragObject As Thing = Nothing
   Private DragOffsetX As Integer
   Private DragOffsetY As Integer

   Private Sub Form1_Load(ByVal sender As _
System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
      L = New ThingList()
      Dim Rnd As New Random()
      L.Add(New Thing(Rnd, Panel1.Width, Panel1.Height))
      L.Add(New Thing(Rnd, Panel1.Width, Panel1.Height))
      L.Add(New Thing(Rnd, Panel1.Width, Panel1.Height))
   End Sub

   Private Sub Panel1_MouseDown(ByVal sender As Object, _
ByVal e As System.Windows.Forms.MouseEventArgs) Handles Panel1.MouseDown
      Me.DragObject = L.GetObjectIfClose(e.X, e.Y)
      If Not DragObject Is Nothing Then
         Me.DragOffsetX = e.X - Me.DragObject.X
         Me.DragOffsetY = e.Y - Me.DragObject.Y
         Me.DragObject.IsDragging = True
         Me.IsDragging = True
         Panel1.Invalidate()
      End If
   End Sub

   Private Sub Panel1_MouseMove(ByVal sender As Object, _
ByVal e As System.Windows.Forms.MouseEventArgs) Handles Panel1.MouseMove
      If Me.IsDragging And Not Me.DragObject Is Nothing Then
         Me.DragObject.X = e.X - Me.DragOffsetX
         Me.DragObject.Y = e.Y - Me.DragOffsetY
         Panel1.Invalidate()
      End If
   End Sub

   Private Sub Panel1_MouseUp(ByVal sender As Object, _
ByVal e As System.Windows.Forms.MouseEventArgs) Handles Panel1.MouseUp
      If Me.IsDragging Then
         Me.IsDragging = False
         L.ResetIsDragging()
         Me.DragObject = Nothing
      End If
      L.MoveToVisibleArea(Panel1.Size)
      Panel1.Invalidate()
   End Sub

   Private Sub Panel1_Paint(ByVal sender As System.Object, _
ByVal e As System.Windows.Forms.PaintEventArgs) Handles Panel1.Paint
      e.Graphics.FillRectangle(Brushes.White, 0, 0, Me.Width, Me.Height)
      L.Draw(e.Graphics)
   End Sub

   Private Sub Panel1_Resize(ByVal sender As Object, _
ByVal e As System.EventArgs) Handles MyBase.Resize
      If Not L Is Nothing Then
         If L.MoveToVisibleArea(Panel1.Size) Then
            Panel1.Invalidate()
         End If
      End If
   End Sub

End Class

Now you can play around with three green boxes in the panel.

Using Mn As New System.Management.ManagementClass("Win32_USBHub")
   Using Devs As System.Management.ManagementObjectCollection _
      = Mn.GetInstances()
      For Each Dev As System.Management.ManagementObject In Devs
         Console.WriteLine(Dev.GetPropertyValue("Name").ToString())
         Console.WriteLine(Dev.GetPropertyValue("DeviceID").ToString())
      Next
   End Using
End Using

My code is written in an console application. The result will be a list of connected USB device names and their unique ID. Have fun!

(The functions are not changed since wrote about them the last time.)

Module Module1

    Sub Main()

        'Create some text.
      Dim S As String = "This is some text that I want to compress. " & _
      "Preferably it's a long string loaded from a text file or some XML document."
      Console.WriteLine("Original string charachter count: {0}", S.Length)

        'Assign the compressed version to the variable B.
      Dim B() As Byte = CompressText(S.ToString())
      Console.WriteLine("Compressed to bytes: {0}", B.Length)

        'Decompress it, and display the result.
      Dim Decompressed As String = DecompressText(B)
      Console.WriteLine("Decompressed text:")
        Console.WriteLine(Decompressed)

      Console.WriteLine()
      Console.Write("Press Enter to quit.")
      Console.ReadLine()

    End Sub

    Private Function CompressText(ByVal T As String) As Byte()
        Dim B() As Byte = System.Text.Encoding.UTF8.GetBytes(T)
        Using MemStream As New System.IO.MemoryStream()
            Using GZStream As New System.IO.Compression.GZipStream(MemStream, _
             IO.Compression.CompressionMode.Compress)
                GZStream.Write(B, 0, B.Length)
                GZStream.Close()
                Return MemStream.ToArray()
            End Using
        End Using
    End Function

    Private Function DecompressText(ByVal B() As Byte) As String
        Dim Result As New System.Text.StringBuilder()
        Using MemStream As New System.IO.MemoryStream(B)
            Using GZStream As New System.IO.Compression.GZipStream(MemStream, _
             IO.Compression.CompressionMode.Decompress)
                Do
                    Dim Buffer(1023) As Byte 'Note that this makes 1024 bytes in VB.
                    Dim BytesRead As Integer = GZStream.Read(Buffer, 0, 1024)
                    If BytesRead > 0 Then
                        Result.Append(System.Text.Encoding.UTF8.GetString(Buffer, 0, BytesRead))
                    End If
                    If BytesRead < 1024 Then
                        Exit Do
                    End If
                Loop
                GZStream.Close()
                Return Result.ToString()
            End Using
        End Using
    End Function

End Module

You will need more data to get a positive effect of compression, and that is one thing to consider when you decide if to compress your data. Another thing to keep in mind is that compressed data isn’t searchable.

If you were to build a web browser, one elementary thing that your program must be able to do, is to make a web request via http and download the response. This ability is also built in into the framework. This function (takes an URL and returns the HTML response) does just that:

Private Function DoWebRequest(ByVal URL As String) As String
   Dim Result As String = ""
   Using Wc As New System.Net.WebClient()
      Dim S As System.IO.Stream = Wc.OpenRead(URL)
      Using R As New System.IO.StreamReader(S)
         Result = R.ReadToEnd()
      End Using
   End Using
   Return Result
End Function

Now, if I do a small change to the program, so that it downloads the response from a specific website, and compresses that, the numbers will be better. This is what the code looks like:

Sub Main()

   'Create some text.
   Dim S As String = DoWebRequest("http://www.hurhomeopatifungerar.se/")
   Console.WriteLine("Original string charachter count: {0}", S.Length)

   'Assign the compressed version to the variable B.
   Dim B() As Byte = CompressText(S.ToString())
   Console.WriteLine("Compressed to bytes: {0}", B.Length)

   'Decompress it, and display the result.
   Dim Decompressed As String = DecompressText(B)
   Console.WriteLine("Decompressed text:")
   Console.WriteLine(Decompressed)

   Console.WriteLine()
   Console.Write("Press Enter to quit.")
   Console.ReadLine()

End Sub

This specific website gives a 2179 characters long response, that is compressed to 1359 bytes. This is the complete code:

Module Module1

    Sub Main()

        'Create some text.
      Dim S As String = DoWebRequest("http://www.hurhomeopatifungerar.se/")
      Console.WriteLine("Original string charachter count: {0}", S.Length)

        'Assign the compressed version to the variable B.
      Dim B() As Byte = CompressText(S.ToString())
      Console.WriteLine("Compressed to bytes: {0}", B.Length)

        'Decompress it, and display the result.
      Dim Decompressed As String = DecompressText(B)
      Console.WriteLine("Decompressed text:")
        Console.WriteLine(Decompressed)

      Console.WriteLine()
      Console.Write("Press Enter to quit.")
      Console.ReadLine()

    End Sub

   Private Function DoWebRequest(ByVal URL As String) As String
      Dim Result As String = ""
      Using Wc As New System.Net.WebClient()
         Dim S As System.IO.Stream = Wc.OpenRead(URL)
         Using R As New System.IO.StreamReader(S)
            Result = R.ReadToEnd()
         End Using
      End Using
      Return Result
   End Function

    Private Function CompressText(ByVal T As String) As Byte()
        Dim B() As Byte = System.Text.Encoding.UTF8.GetBytes(T)
        Using MemStream As New System.IO.MemoryStream()
            Using GZStream As New System.IO.Compression.GZipStream(MemStream, _
             IO.Compression.CompressionMode.Compress)
                GZStream.Write(B, 0, B.Length)
                GZStream.Close()
                Return MemStream.ToArray()
            End Using
        End Using
    End Function

    Private Function DecompressText(ByVal B() As Byte) As String
        Dim Result As New System.Text.StringBuilder()
        Using MemStream As New System.IO.MemoryStream(B)
            Using GZStream As New System.IO.Compression.GZipStream(MemStream, _
             IO.Compression.CompressionMode.Decompress)
                Do
                    Dim Buffer(1023) As Byte 'Note that this makes 1024 bytes in VB.
                    Dim BytesRead As Integer = GZStream.Read(Buffer, 0, 1024)
                    If BytesRead > 0 Then
                        Result.Append(System.Text.Encoding.UTF8.GetString(Buffer, 0, BytesRead))
                    End If
                    If BytesRead < 1024 Then
                        Exit Do
                    End If
                Loop
                GZStream.Close()
                Return Result.ToString()
            End Using
        End Using
    End Function

End Module

Now I want to enable shooting. When the user presses the Control key, I create a bullet, sets its properties and adds it to the engine. This code is added to the KeyDown event. I have to modify the KeyUp event, because in the previous version, it unconditionally made the ship stop. Now when more keys are involved, I only want the ship to stop if it is the up or down buttons are released.

This is the new version of the KeyDown event:

   Private Sub Form1_KeyDown(ByVal _
sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
      If e.KeyData = Keys.A Then

         'If user presses "a", move up!
         Me.PlayerMover.DestY = 0
         Me.PlayerMover.SpeedY = -2

      ElseIf e.KeyData = Keys.Z Then

         'If user presses "z", move down!
         Me.PlayerMover.DestY = SpriteSurface1.Height
         Me.PlayerMover.SpeedY = 2

      End If

      If (e.KeyData And Keys.ControlKey) = Keys.ControlKey Then

         'If user presses Control, fire!
         Dim Bullet As New SCG.TurboSprite.PolygonSprite(2, 0, -2, 1, -2, -1)
         Bullet.Position = New Point(Player.Position.X + 15, Player.Position.Y + 9)
         Bullet.Color = Color.Cyan
         SpriteEngineDestination1.AddSprite(Bullet)
         Dim BulletMover As SCG.TurboSprite.DestinationMover = _
SpriteEngineDestination1.GetMover(Bullet)
         BulletMover.Destination = New Point(SpriteSurface1.Width + 5, _
Bullet.Height)
         BulletMover.SpeedX = 4

      End If
   End Sub

This is the new version of the KeyUp event:

   Private Sub Form1_KeyUp(ByVal sender As _
Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp

      'Stop moving, but only if "a" or "z" is released.
      If e.KeyData = Keys.A Or e.KeyCode = Keys.Z Then
         Me.PlayerMover.SpeedY = 0
      End If

   End Sub

Finally, when a bullet reaches its destination at the right end of the screen, I want it deleted. Check the SpriteReachedDestination event in the final code listing below.

When this is all working, I want to add an enemy and use the collision detection to see if it was killed. I did not subclass the PolygonSprite, and this is really something you should do to be able to tag the sprites. The “ugly hack” of this post, must be that I use color to determine if the sprite is a bullet, or the enemy. This is the complete code:

Public Class Form1

   'A reference to the player (created in the Shown event) and the mover.
   Private Player As SCG.TurboSprite.PolygonSprite
   Private PlayerMover As SCG.TurboSprite.DestinationMover

   Private Sub Form1_Shown(ByVal sender _
As Object, ByVal e As System.EventArgs) Handles Me.Shown

      'Set the desired number of frames per second and activate the surface.
      SpriteSurface1.DesiredFPS = 40
      SpriteSurface1.Active = True

      'Create the player and save the reference.
      Me.Player = New SCG.TurboSprite.PolygonSprite(-20, -10, 20, 10, -20, 10)

      'Set player original position.
      Me.Player.Position = New Point(100, 100)

      'Set player color.
      Me.Player.Color = Color.Yellow

      'Add the player to the sprite engine.
      SpriteEngineDestination1.AddSprite(Me.Player)

      'Save a reference to the mover.
      Me.PlayerMover = SpriteEngineDestination1.GetMover(Me.Player)

      'Now, add an ENEMY!
      Dim Enemy As New SCG.TurboSprite.PolygonSprite(-30, 20, 0, -20, 30, 20)
      Enemy.Position = New Point(SpriteSurface1.Width, SpriteSurface1.Height)
      Enemy.Color = Color.Red
      SpriteEngineDestination1.AddSprite(Enemy)
      Dim EnenyMover As SCG.TurboSprite.DestinationMover = _
SpriteEngineDestination1.GetMover(Enemy)
      EnenyMover.Speed = 1
      EnenyMover.Destination = New Point(-50, 100)

   End Sub

   Private Sub Form1_KeyDown(ByVal sender As _
Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
      If e.KeyData = Keys.A Then

         'If user presses "a", move up!
         Me.PlayerMover.DestY = 0
         Me.PlayerMover.SpeedY = -2

      ElseIf e.KeyData = Keys.Z Then

         'If user presses "z", move down!
         Me.PlayerMover.DestY = SpriteSurface1.Height
         Me.PlayerMover.SpeedY = 2

      End If

      If (e.KeyData And Keys.ControlKey) = Keys.ControlKey Then

         'If user presses Control, fire!
         Dim Bullet As New SCG.TurboSprite.PolygonSprite(2, 0, -2, 1, -2, -1)
         Bullet.Position = New Point(Player.Position.X + 15, Player.Position.Y + 9)
         Bullet.Color = Color.Cyan
         SpriteEngineDestination1.AddSprite(Bullet)
         Dim BulletMover As SCG.TurboSprite.DestinationMover = _
SpriteEngineDestination1.GetMover(Bullet)
         BulletMover.Destination = New Point(SpriteSurface1.Width + 5, _
Bullet.Height)
         BulletMover.SpeedX = 4

      End If
   End Sub

   Private Sub Form1_KeyUp(ByVal sender As Object, ByVal _
e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp

      'Stop moving, but only if "a" or "z" is released.
      If e.KeyData = Keys.A Or e.KeyCode = Keys.Z Then
         Me.PlayerMover.SpeedY = 0
      End If

   End Sub

   Private Sub SpriteEngineDestination1_SpriteReachedDestination(ByVal sender As _
Object, ByVal e As SCG.TurboSprite.SpriteEventArgs) Handles SpriteEngineDestination1.SpriteReachedDestination
      'You really should subclass the bullet to be able to
      'tag it as a bullet. I use color. Hack!!!
      Dim P As SCG.TurboSprite.PolygonSprite = CType(e.Sprite, SCG.TurboSprite.PolygonSprite)
      If P.Color = Color.Cyan Then
         P.Kill()
         SpriteEngineDestination1.RemoveSprite(P)
      End If
   End Sub

   Private Sub SpriteSurface1_SpriteCollision(ByVal sender As _
Object, ByVal e As SCG.TurboSprite.SpriteCollisionEventArgs) Handles SpriteSurface1.SpriteCollision
      'Did the player shoot the enemy? Is one a bullet and one the enemy?
      'Again, I use color. Hack!!!
      Dim FirstSprite As SCG.TurboSprite.PolygonSprite = CType(e.Sprite1, _
SCG.TurboSprite.PolygonSprite)
      Dim SecondSprite As SCG.TurboSprite.PolygonSprite = CType(e.Sprite2, _
SCG.TurboSprite.PolygonSprite)
      If FirstSprite.Color = Color.Cyan Then
         'We have a bullet.
         If SecondSprite.Color = Color.Red Then
            'And the enemy.
            SecondSprite.Kill()
            SpriteEngineDestination1.RemoveSprite(SecondSprite)
         End If
      ElseIf FirstSprite.Color = Color.Red Then
         'We have the enemy.
         If SecondSprite.Color = Color.Cyan Then
            'And a bullet.
            FirstSprite.Kill()
            SpriteEngineDestination1.RemoveSprite(FirstSprite)
         End If
      End If
   End Sub

End Class

Again, subclass and add your own properties! Do not use color to determine what sprite you are dealing with. This is the result:

Thank you, TurboSprite!

In this first part, I will create a player (a spaceship) that can respond to keyboard control. In the second part, the player will be able to shoot and kill enemies.

To start off, I create a project, I add a sprite surface and an sprite engine destination. I connect them to each other by setting the Surface property of the engine. Also, I intend to use collision detection, so I set the DetectCollisionSelf property to True.

On the surface, I set the AutoBlank property to True and the AutoBlankColor property to Black. On the form, I set KeyPreview to True.

Note that so far, all the magic is happening in KeyDown, KeyUp (input feedback) and Shown (initialization).

Public Class Form1

   'A reference to the player (created in the Shown event) and the mover.
   Private Player As SCG.TurboSprite.PolygonSprite
   Private PlayerMover As SCG.TurboSprite.DestinationMover

   Private Sub Form1_Shown(ByVal sender As Object, ByVal e As _
System.EventArgs) Handles Me.Shown

      'Set the desired number of frames per second and activate the surface.
      SpriteSurface1.DesiredFPS = 40
      SpriteSurface1.Active = True

      'Create the player and save the reference.
      Me.Player = New SCG.TurboSprite.PolygonSprite(-20, -10, 20, 10, -20, 10)

      'Set player original position.
      Me.Player.Position = New Point(100, 100)

      'Set player color.
      Me.Player.Color = Color.Yellow

      'Add the player to the sprite engine.
      SpriteEngineDestination1.AddSprite(Me.Player)

      'Save a reference to the mover.
      Me.PlayerMover = SpriteEngineDestination1.GetMover(Me.Player)

   End Sub

   Private Sub Form1_KeyDown(ByVal sender As Object, ByVal _
e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
      If e.KeyData = Keys.A Then

         'If user presses "a", move up!
         Me.PlayerMover.DestY = 0
         Me.PlayerMover.SpeedY = -2

      ElseIf e.KeyData = Keys.Z Then

         'If user presses "z", move down!
         Me.PlayerMover.DestY = SpriteSurface1.Height
         Me.PlayerMover.SpeedY = 2

      End If
   End Sub

   Private Sub Form1_KeyUp(ByVal sender As Object, ByVal _
e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyUp

      'Stop moving!
      Me.PlayerMover.SpeedY = 0

   End Sub

End Class

Continued here.

To be able to use TurboSprite, download and compile it, add the components to your toolbox. Then, add a surface and an engine to a form. Note that you have two engines. One is called SpriteEngine and another is called SpriteEngineDestination. Use the SpriteEngineDestination object, because it extends the SpriteEngine class with the ability to move sprites. You might want to set a few properties to connect the engine to the surface, to tell the engine if you want collision detection and so on. Collision detection is a reasonable cause for using a sprite engine. I use the AutoBlank feature of the surface.

About the moving of the sprites, you can acquire the sprite mover using the GetMover function for the engine (if you use the SpriteEngineDestination), and set the X and Y speed of a sprite. Or you can do as I do in this example below. That is, just set a speed and a destination position. The destination position determines the sprite movement direction.

This code does two thinks (written in the Show event of a regular form). The first line activates the sprite engine so that sprites will move. The rest of the code initializes one vector sprite.

'When the form is loaded, activate the surface
SpriteSurface1.Active = True

'Create a space ship. These points makes a ship.
Dim S As New SCG.TurboSprite.PolygonSprite(0, -10, 5, 10, 0, 5, -5, 10)

'Tell the sprite to rotate.
S.Spin = SCG.TurboSprite.SpinType.Clockwise
S.SpinSpeed = 3

'Start position.
S.Position = New Point(30, 30)

'Add the sprite to the engine, and acquire the sprite mover from the engine.
SpriteEngineDestination1.AddSprite(S)
Dim Mover As SCG.TurboSprite.DestinationMover = SpriteEngineDestination1.GetMover(S)

'Tell the mover about speed and direction.
Mover.Speed = 5
Mover.Destination = New Point(50, 40)

'Tell the mover that the destination really isn't a destination,
'it's just used as a direction.
Mover.StopAtDestination = False

This is the sprite:

Download the engine from the Code Project web site.

Private Function DecompressText(ByVal B() As Byte) As String
   Dim Result As New System.Text.StringBuilder()
   Using MemStream As New System.IO.MemoryStream(B)
      Using GZStream As New System.IO.Compression.GZipStream(MemStream, _
         IO.Compression.CompressionMode.Decompress)
      Do
         'Note that this makes 1024 bytes in VB.
         Dim Buffer(1023) As Byte
         Dim BytesRead As Integer = GZStream.Read(Buffer, 0, 1024)
         If BytesRead > 0 Then
            Result.Append( _
               System.Text.Encoding.UTF8.GetString(Buffer, 0, BytesRead))
         End If
         If BytesRead < 1024 Then
            Exit Do
         End If
      Loop
      GZStream.Close()
      Return Result.ToString()
      End Using
   End Using
End Function

Now, imagine that B is a byte array returned from the CompressText function. B holds the bytes of a compressed text string. B is passed to the DecompressText function and the function returns the inflated string again. Example:

'Create some text.
Dim S As String = "This is some text that I want to compress. Preferably it's " & _
"a long string loaded from a text file or some XML document."

'Assign the compressed version to the variable B.
Dim B() As Byte = CompressText(S.ToString())

'Decompress it, and display the result.
Dim Decompressed As String = DecompressText(B)
Console.WriteLine(Decompressed)

Have you seen a more elegant way to handle strings in memory than what the .NET Framework offers?

The table option you must set, to be allowed to insert a value in an identity column is called IDENTITY_INSERT. So add this line to your command object to make it work:

SET IDENTITY_INSERT dbo.Products ON;

The following INSERT statement can give a value to the identity column, if the value complies with the rules for that column. The line of code could look something like this:

Using X As New SqlClient.SqlCommand( _
    "SET IDENTITY_INSERT dbo.Products ON; INSERT...

The ArgumentExists function checks for the presence of an argument and the GetIndexOfArgument function gives you the index of an argument, or negative one if not present. The GetArgumentParameter returns the argument next to a given argument.

Let’s say that you are writing an application called test.exe, and it is started like this:

test.exe -f hello -qq "hello again"

If you pass “-qq” to the GetArgumentParameter function, it will return “hello again“. If you pass “-f” to the ArgumentExists function, it returns true. And if you pass “yeah” to the GetIndexOfArgument function, it returns -1.

Example:

Dim Args As New CommandLineArguments()
Console.WriteLine("Param: " & Args.ArgumentExists("-f").ToString())
Console.ReadLine()

This is the source code for the class:

Public Class CommandLineArguments
    Inherits CollectionBase

    Private mIgnoreCase As Boolean

    Public Sub New()
        Me.New(True)
    End Sub

    Public Sub New(ByVal IgnoreCase As Boolean)
        Dim S() As String = System.Environment.GetCommandLineArgs()
        If S.Length > 1 Then
            For I As Integer = 1 To S.Length - 1
                List.Add(S(I))
            Next
        End If
        Me.mIgnoreCase = IgnoreCase
    End Sub

    Default Public ReadOnly Property Item(ByVal Index As Integer) As String
        Get
            Return CType(List(Index), String)
        End Get
    End Property

    Public Function ArgumentExists(ByVal Arg As String) As Boolean
        For Each S As String In Me
            If String.Compare(S, Arg, Me.mIgnoreCase) = 0 Then
                Return True
            End If
        Next
        Return False
    End Function

    Public Function GetIndexOfArgument(ByVal Arg As String) As Integer
        If Me.Count > 0 Then
            For I As Integer = 0 To Me.Count - 1
                If String.Compare(Me(I), Arg, Me.mIgnoreCase) = 0 Then
                    Return I
                End If
            Next
            Return -1
        Else
            Return -1
        End If
    End Function

    Public Function GetArgumentParameter(ByVal Arg As String) As String
        Dim Index As Integer = Me.GetIndexOfArgument(Arg)
        If Index > -1 Then
            If Index < (Me.Count - 1) Then
                Return Me(Index + 1)
            Else
                Return ""
            End If
        Else
            Return ""
        End If
    End Function

End Class

The following example requires a form with a textbox (TextBox1) and a data grid view (DataGridView1). To use the application, just type something in the textbox, and watch the grid filtering its records. The Load event of the form populates the grid. The TextChanged of the textbox filters the grid.

Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

    'Configure the data grid view.
    DataGridView1.ReadOnly = True
    DataGridView1.Columns.Add("ColA", "Some column")
    DataGridView1.Columns.Add("ColB", "Some other column")
    DataGridView1.AllowUserToAddRows = False
    DataGridView1.SelectionMode = DataGridViewSelectionMode.FullRowSelect
    DataGridView1.Rows.Clear()

    'Add lots of rows.
    For A As Integer = 500 To 999
        Dim Index As Integer = DataGridView1.Rows.Add()
        DataGridView1.Rows(Index).Cells(0).Value = A.ToString("000")
        DataGridView1.Rows(Index).Cells(1).Value = "Hello"
    Next

    'Add two rows with some names in them.
    Dim Temp As Integer = DataGridView1.Rows.Add()
    DataGridView1.Rows(Temp).Cells(0).Value = "Anders"
    DataGridView1.Rows(Temp).Cells(1).Value = "Bengt"

    Temp = DataGridView1.Rows.Add()
    DataGridView1.Rows(Temp).Cells(0).Value = "Calle"
    DataGridView1.Rows(Temp).Cells(1).Value = "David"

    'Again, add lots of rows.
    For A As Integer = 300 To 999
        Dim Index As Integer = DataGridView1.Rows.Add()
        DataGridView1.Rows(Index).Cells(0).Value = A.ToString("000")
        DataGridView1.Rows(Index).Cells(1).Value = "Good bye"
    Next

    'Now we have 1.202 rows in the grid. Do some resizing of the columns.
    DataGridView1.AutoResizeColumns()

End Sub

Private Sub TextBox1_TextChanged(ByVal _
     sender As System.Object, ByVal e As System.EventArgs) Handles TextBox1.TextChanged
    If DataGridView1.RowCount > 0 Then

        'What is the user searching for? Remove case information.
        Dim SearchFor As String = TextBox1.Text.ToLower().Trim()

        'If the user has cleared the search box, show all rows.
        If SearchFor = "" Then
            For I As Integer = 0 To DataGridView1.Rows.Count - 1
                DataGridView1.Rows(I).Visible = True
            Next
        Else

            'When the user types something in the textbox, search for
            'rows with cells that holds that value.
            For I As Integer = 0 To DataGridView1.Rows.Count - 1

                'Extract the values from the grid. Remove case information.
                Dim ColA As String = CType(DataGridView1.Rows(I).Cells(0).Value, _
String).ToLower()
                Dim ColB As String = CType(DataGridView1.Rows(I).Cells(1).Value, _
String).ToLower()

                'Show only matching rows.
                If ColA.IndexOf(SearchFor) > -1 OrElse ColB.IndexOf(SearchFor) > -1 Then
                    DataGridView1.Rows(I).Visible = True
                Else
                    DataGridView1.Rows(I).Visible = False
                End If

            Next
        End If

        'Select the first visible row.
        For I As Integer = 0 To DataGridView1.Rows.Count - 1
            If DataGridView1.Rows(I).Visible Then
                DataGridView1.CurrentCell = DataGridView1.Rows(I).Cells(0)
                Exit For
            End If
        Next

    End If
End Sub